home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 27 / CU Amiga Magazine's Super CD-ROM 27 (1998)(EMAP Images)(GB)[!][issue 1998-10].iso / InitCD < prev    next >
AmigaDOS Script File  |  1998-08-04  |  6KB  |  196 lines
  1. .key arg
  2. .bra {
  3. .ket }
  4.  
  5. ; CUCD Init Script
  6. ;
  7. ; Set up assigns etc. both for users booting from the CD and from  HD
  8. ;
  9. ; Version 1.1 - Changed jpegtmp
  10. ;
  11. ; Version 1.2 - Added uninit option
  12. ;
  13. ; Version 1.3 - Added CHECK argument and link to Prefs editor
  14. ;
  15. ; Version 1.4 - Added section to copy CUCDfile and IDer.prefs to hard drive if not already present
  16. ;
  17. ; Version 1.5 - Got rid of calls to updatecopy and replaced them with version/if warn
  18. ;               Hopefully cured the problem of the CD icon not leaving Workbench after running UninitCD
  19.  
  20. Assign CUCD: :
  21.  
  22. ;;; Make some commands resident to speed up things on CD32s in particular
  23. Resident >NIL: CUCD:C/RequestChoice PURE
  24. Resident >NIL: CUCD:rexxc/rx PURE
  25. Resident >NIL: CUCD:C/Version PURE
  26. ;;;
  27. ;;; Exit if InitCD has been run, otherwise ask
  28. If {arg} EQ "CHECK"
  29.     If $CDInit EQ TRUE
  30.         Skip END
  31.     Else
  32.         set init `CUCD:C/RequestChoice "CU Amiga CD" "InitCD needs to be run first*NWould you like to run it now?" "Yes|No"`
  33.         If $init EQ 0
  34.             Skip END
  35.             EndIf
  36.         EndIf
  37.     EndIf
  38. ;;;
  39. ;;; Give option to run UninitCD
  40. If $CDInit EQ TRUE
  41.     If $CDBoot EQ TRUE          ; don't run UninitCD if booted from CD
  42.         CUCD:C/RequestChoice >NIL: "CU Amiga CD" "You do not need to run InitCD*Nwhen you have booted from the CD" "OK" 
  43.         Skip END
  44.         EndIf
  45.     set remass `CUCD:C/RequestChoice "InitCD" "You have already run InitCD once.*NDo you wish to remove the assigns and paths added before?" "Remove|Cancel"`
  46.     If $remass EQ 1
  47.         execute UnInitCD
  48.         EndIf
  49.     Skip END
  50.     EndIf
  51. ;;;
  52. ;;; Set some system assigns and paths
  53. ;;;
  54. ;;; Add MUI if no MUI installed.
  55. Assign MUI: EXISTS >NIL:
  56. IF WARN
  57.     Assign MUI:    CUCD:CDsupport/MUI
  58.     Assign Libs:   MUI:Libs ADD
  59.     Assign LOCALE: MUI:Locale ADD
  60.     Assign HELP: EXISTS >NIL:
  61.     If NOT WARN
  62.         Dir >NIL: HELP:
  63.         EndIf
  64.     Assign HELP:   MUI:Docs ADD
  65.     EndIf
  66. ;;;
  67. ;;; Set assigns and paths for programs on this CD
  68. Execute CUCD:S/ThisCD
  69. ;;;
  70. ;;;BEGIN ClassAct
  71. CUCD:C/CAPrefs >NIL:
  72. ;;;END ClassAct
  73. ;;; Commands to be run only if booting from CD
  74. IF $CDBoot EQ TRUE
  75.     Run <NIL: >NIL: C:NewIcons
  76.     CUCD:C/DefIcons
  77.  
  78.     ; Run these only if booting from a real CD32
  79.     Version >NIL:
  80.     if $kickstart EQ "40.60"
  81.         ;C:CD2XSpeed
  82.         C:NoReset
  83.         EndIf
  84.  
  85.     ; Allow alternative screenmodes
  86.     if $CUCDscreen EQ "NTSC"
  87.         :Storage/Monitors/NTSC
  88.         :Prefs/ScreenMode from :Prefs/Presets/NTSC USE
  89.         :Prefs/Input from :Prefs/Presets/USkey USE
  90.         setenv VisageOpts MONITOR=NTSC
  91.         endif
  92.     if $CUCDscreen EQ "VGA"
  93.         :Storage/Monitors/DblPAL
  94.         :Prefs/ScreenMode from :Prefs/Presets/VGA USE
  95.         setenv VisageOpts MONITOR=DblPAL
  96.         endif
  97.     unsetenv CUCDscreen
  98. ;;;
  99. ;;; All this is only needed when not booting from the CD
  100. Else
  101.     ; Make sure LIBS: has up to date copy of asyncio.library, to fix problems with earlier InitCD
  102.     Version >NIL: LIBS:asyncio.library 39 2 file
  103.     If WARN
  104.         copy CUCD:Libs/asyncio.library LIBS: CLONE
  105.         EndIf
  106.  
  107.     ; add CD assigns and paths
  108.     Assign DEVS:    CUCD:Devs ADD
  109.     Assign Fonts:   CUCD:Fonts ADD
  110.     Assign Libs:    CUCD:Libs ADD
  111.     Assign L:       CUCD:L ADD
  112.     Assign S:       CUCD:S ADD
  113.     Assign LIBS:    CUCD:Classes ADD
  114.     Path CUCD:C CUCD:CDsupport CUCD:System CUCD:Utilities CUCD:S CUCD:Rexxc ADD
  115.  
  116.     ; Start arexx if not running
  117.     CUCD:rexxc/rx "address command" >NIL:
  118.     If WARN
  119.         CUCD:System/RexxMast >NIL:
  120.         EndIf
  121.     ; Make sure icon.mcc is available for CUCDprefs
  122.     Version >NIL: MUI:Libs/MUI/Icon.mcc 1 1
  123.     If WARN
  124.         Copy >NIL: CUCD:CDsupport/MUI/Libs/MUI/Icon.mcc MUI:Libs/MUI CLONE
  125.         EndIf
  126.  
  127.     ; Give option for setting CD preferences, make sure CUCDfile and IDer
  128.     ; are in basic command path, so it will run without InitCD
  129.     If NOT EXISTS C:CUCDfile
  130.         Copy >NIL: CUCD:C/CUCDfile C: CLONE
  131.         EndIf
  132.     Version >NIL: C:IDer 1 6
  133.     If WARN
  134.         Copy >NIL: CUCD:C/IDer C: CLONE
  135.         EndIf
  136.     ; ensure IDer.prefs are available
  137.     If NOT EXISTS ENV:IDer.prefs
  138.         If NOT EXISTS S:IDer.prefs
  139.             Version >NIL: version 39
  140.             If NOT WARN
  141.                 Copy >NIL: CUCD:S/IDer.prefs S:IDer.prefs
  142.                 set edit `RequestChoice "CU Amiga CD" "CUCD now has a preferences program to specify*N the tools used to view/hear different types of files.*NWould you like to run it now?" "Yes|No"`
  143.                 If $edit EQ 1
  144.                     cd CUCD:S
  145.                     :RexxC/MuiRexx CUCDPrefs.mrx port CDPREFS
  146.                 Else
  147.                     RequestChoice >NIL: "CU Amiga CD" "You can run CUCD preferences at any time.*NIt is in the Prefs drawer of the CD" "OK"
  148.                     EndIf
  149.             Else
  150.                 Copy >NIL: CUCD:S/IDer.prefs_OS2 ENV:IDer.prefs
  151.                 EndIf
  152.             EndIf
  153.         EndIf
  154.  
  155.     ; Make environment variables defined on CD available to system
  156.     Failat 21
  157.     Assign >NIL: ENV: CUCD:Prefs/Env-Archive ADD
  158.     ; For HappyENV users
  159.     If FAIL     
  160.         Assign >NIL: ENVARC: CUCD:Prefs/Env-Archive ADD
  161.         EndIf
  162.  
  163.     ;Start NewIcons if not already running
  164.     If $NoNewIcons NOT EQ TRUE
  165.         CUCD:C/isnirunning
  166.         If NOT WARN
  167.             Run <NIL: >NIL: CUCD:C/NewIcons
  168.             CUCD:C/DefIcons
  169.             EndIf
  170.         EndIf
  171.  
  172.     ; Update workbench paths unless running Directory Opus 5.11 or 5.5 in WBR mode
  173.     Version >NIL: C:LoadWB 43
  174.     If WARN
  175.        C:LoadWB NEWPATH
  176.     Else
  177.         Version >NIL: C:LoadWB 60
  178.         If NOT WARN
  179.             C:LoadWB NEWPATH
  180.             EndIf
  181.         EndIf
  182.  
  183.     RequestChoice >NIL: "InitCD" "InitCD has set up some assigns and paths to run software from the CD.*NIf you wish to remove the CD from the drive, run InitCD again,*Notherwise the icon will stay on your Workbench." " OK "
  184.     EndIf
  185. ;;;
  186. SetEnv CDInit TRUE
  187.  
  188. LAB END
  189.  
  190. ;;; Remove commands made resident earlier
  191. Resident >NIL: RequestChoice REMOVE
  192. Resident >NIL: rx REMOVE
  193. Resident >NIL: Version REMOVE
  194. ;;;
  195.  
  196.